% Structure of the family:
%
%                    Christine oo Heinz  Maria oo Fritz
%                      /    \               |
%                     /      \              |
%      Monika oo Herbert    Angelika oo Hubert
%       /  \                   |
%      /    \                  |
%  Susanne  Norbert          Andreas


% Definition der Ehefrau-Ehemann-Relation:
ehemann(christine, heinz).
ehemann(maria,     fritz).
ehemann(monika,    herbert).
ehemann(angelika,  hubert).

% Definition der Kind-Mutter-Relation:
mutter(herbert, christine).
mutter(angelika,christine).
mutter(hubert,  maria).
mutter(susanne, monika).
mutter(norbert, monika).
mutter(andreas, angelika).

% spezielle Schlussfolgerungen:
%vater(norbert,herbert) :- mutter(norbert,monika), ehemann(monika,herbert).
%vater(susanne,herbert) :- mutter(susanne,monika), ehemann(monika,herbert).
%vater(heinz,herbert) :- mutter(heinz,monika), ehemann(monika,herbert).
% Allgemeine Regel:
vater(Kind,Vater) :- mutter(Kind,Mutter), ehemann(Mutter,Vater).

% Enkel-Grossvater-Beziehung:
grossvater(E,G) :- vater(E,V), vater(V,G).
grossvater(E,G) :- mutter(E,M), vater(M,G).

% Ist eine Person ein Ehemann?
istEhemann(P) :- ehemann(_,P).

% Liste aller Muetter:
muetter(Ms) :- findall(M, mutter(_,M), Ms).

% Alle Grossvaeter:
grossvaeter(Gs) :- findall(G, grossvater(_,G), Gs).

kind_muetter(KMs) :- findall((K,M) , mutter(K,M), KMs).

enkel_grossvaeter(Gs) :- findall((E,G) , grossvater(E,G), Gs).

% Kinder einer Mutter:
%kinder(M,Ks) :- findall(K, mutter(K,M), Ks).
kinder(M,Ks) :- bagof(K, mutter(K,M), Ks).

%vaeter(Vs) :- bagof(V, vater(_,V), Vs).

isVater(V) :- vater(_,V).

%vaeter(Vs) :- bagof(V, isVater(V), Vs).
%vaeter(Vs) :- bagof(V, K^vater(K,V), Vs).
vaeter(Vs) :- setof(V, K^vater(K,V), Vs).